Windows 時刻同期コマンド　バッチファイル

時刻をインターネット同期するコマンド

時刻同期コマンドのご紹介です。これは一例なので自由にアレンジできます。

作成しておくとワンクリックで時刻同期できるので便利です。

@echo off
rem ■■W32Timeサービス開始判定あり 時刻同期 bat■■

rem ----- 管理者権限で実行 -----
echo.
echo コマンドプロンプトを管理者として実行します
echo.

for /f "tokens=3 delims=\ " %%A in ('whoami /groups^|find "Mandatory"') do set LEVEL=%%A
if not "%LEVEL%"=="High" (
powershell -NoProfile -ExecutionPolicy Unrestricted -Command "Start-Process \"%~f0\" -Verb runas"
exit
)

rem --Windows Timeサービス W32Time状態判定--
sc query W32Time | findstr STATE | findstr RUNNING > NUL
if %ERRORLEVEL% neq 0 (
rem --Windows Timeサービス W32Timeを開始--
echo.
echo ==============================================
echo 　Windows Timeサービス W32Timeを開始します。
echo ==============================================
echo.
net start W32Time
timeout /T 3 > NUL
)

rem --時刻同期--
echo.
echo ====================
echo 　時刻同期します。
echo ====================
echo.

w32tm /resync

echo.
echo ===========================
echo 　最終時刻同期時間を確認
echo ===========================
echo.

w32tm /query /status
echo 終了します。
timeout /T 3
exit

W32Timeサービスが開始していない場合はサービス開始後同期します。すでに開始している場合は時刻同期のみです。

「はい」をクリックして続行します。

更新
2019/11/25

「W32Timeサービス」を開始した場合、タイミングが合わず同期出来ないことがあるので、25行目で同期するタイミングを3秒遅らせました。
※開始されていた場合は、関係ありません。

メモ帳で保存する場合の文字コードについて、Ver1903からUTF-8が規定値になりBOMが入らなくなりましたが、echoで日本語表示すると文字化けします。
ANSIで保存することをおススメします。
　　

まれな現象として、

上記メッセージが出ることがあります。
原因は多々考えられますが、通常は再度実行することで解消されます。コマンドを複雑にするよりも再実行をおススメします。（※上記メッセージでも同期出来ていることがあります）

これが正常メッセージです。

エラーメッセージ 対策　再実行不要版を公開しました。↓　再実行が面倒な方へ…

Windows 時刻同期コマンド　エラー対策 再実行不要版 バッチファイル

時刻同期コマンド　エラーメッセージ 対策 時刻同期コマンドを実行した際の出力メッセージは、 再同期コマンドをローカル コンピューターに送信していますコマンドは正しく完了しました。 上記が正常なのですが、まれに、 再同期コマンドをローカル コ...

amksystem.com

2020.03.13

slewモードとstepモード

Windows 精密な時刻同期

時刻同期を細かく設定 強制的に時刻同期する場合、数秒以上ずれている場合に同期されます。 1秒以内のずれであれば同期しない設定になっているようです。 誤差1秒以内でも時刻同期する （通常誤差1秒以内※であれば直ちに時刻同期しないslewモード...

amksystem.com

2017.04.18