PR

Windows Update フォルダ リセット コマンド

スポンサーリンク

Windows Update フォルダ リセット コマンド

Windows Update を実行しているファイル・フォルダをリネーム(削除)し、リセットします。

自己責任になるので、分かる方のみご利用してください。

※管理者として実行してください。

@echo off

rem ■Windows Update フォルダ リセット bat■

rem ----- 管理者権限で実行 -----
echo.
echo コマンドプロンプトを管理者として実行します
echo.

for /f "tokens=3 delims=\ " %%A in ('whoami /groups^|find "Mandatory"') do set LEVEL=%%A
if not "%LEVEL%"=="High" (
powershell -NoProfile -ExecutionPolicy Unrestricted -Command "Start-Process \"%~f0\" -Verb runas"
exit
)

echo.
echo Windows update フォルダをリセットします。
echo.
echo ******************************************************************************
echo 「UsoSvc」「DoSvc」「wuauserv」「CryptSvc」「BITS」「msiserver」サービス停止
echo 「SoftwareDistribution」フォルダ「.old」リネーム
echo 「System32\catroot2」フォルダ「.old」リネーム
echo 「%ALLUSERSPROFILE%\Microsoft\Network\Downloader\qmgr0.dat」 削除
echo 「%ALLUSERSPROFILE%\Microsoft\Network\Downloader\qmgr1.dat」 削除
echo 再起動 選択
echo 「UsoSvc」「DoSvc」「wuauserv」「cryptSvc」「bits」「msiserver」サービス開始
echo ******************************************************************************
echo.
echo Yを選択するとWindows update フォルダをリセットします。
echo.

set Try=N
set /p Try="フォルダをリセットしますか? [Y/N*空白](N*空白=終了)="
if defined Try set Try=%Try:"=%
if /i NOT "%Try%" == "y" exit

net stop UsoSvc
net stop DoSvc
net stop wuauserv
net stop CryptSvc
net stop BITS
net stop msiserver
ren %systemroot%\SoftwareDistribution SoftwareDistribution.old
ren %systemroot%\System32\catroot2 catroot2.old
del "%ALLUSERSPROFILE%\Microsoft\Network\Downloader\qmgr0.dat"
del "%ALLUSERSPROFILE%\Microsoft\Network\Downloader\qmgr1.dat"

:Select
echo.
echo リセットしました。
echo 処理方法を選択して下さい。
echo -------------------------
echo [R] 再起動
echo [S] サービス開始
echo [E/空Enter] コマンド終了
echo -------------------------

set Sel=E
set /p Sel="実行する記号を入力して下さい="
if defined Sel set Sel=%Sel:"=%
if /i "%Sel%" == "R" goto :Re
if /i "%Sel%" == "S" goto :Sv
if /i "%Sel%" == "E" exit
goto :Error

:Re
rem --- 再起動 ---
echo 再起動します。
shutdown /r /t 3

:Sv
rem --- サービス開始 ---
rem net start msiserver
rem net start BITS
net start CryptSvc
rem net start wuauserv
rem net start DoSvc
net start UsoSvc

echo.
echo サービスを開始しました。
echo コマンドを終了します。
echo.
pause
exit

:Error
rem --エラー処理--
color 4f
echo.
echo ===============
echo  入力エラー
echo ===============
echo.
echo 入力された値が正しくありません
echo.
pause
color 07
goto :Select

(不要なrem行を含んでいます)

正常動作を確認後、リネームしたフォルダの削除ができます。


備考

<cmd>
wuauclt /resetauthorization /detectnow(コマンドサービス終了)
usoclient StartScan
<PowerShell>
(New-Object -ComObject Microsoft.Update.AutoUpdate).DetectNow()
<タスク>
Microsoft > windows > Update Orchestrator > Schedule Scan

<起動時サービス状態>
UsoSvc] Orchestrator Service の更新 /自動(遅延開始)<実行中>
DoSvc] Delivery Optimization /手動(トリガー開始)<停止>※開始
wuauserv] Windows Update /手動(トリガー開始)<開始>※停止
CryptSvc] Cryptographic Services /自動<実行中>
BITS] Background Intelligent Transfer Service /手動<停止>
msiserver] Windows Installer /手動<停止>

タイトルとURLをコピーしました